Compiler Explorer

Source code

import std.traits : isSomeString;

ulong levenshteinEditDistance(T)(in ref T a, in ref T b) if (isSomeString!T) {
	import std.array : uninitializedArray;

auto matrix = uninitializedArray!(ulong[][])(a.length + 1, b.length + 1);
	foreach (i; 0 .. a.length + 1)
		matrix[i][0] = i;

foreach (j; 0 .. b.length + 1)
		matrix[0][j] = j;

import std.algorithm : min;

for (int i = 1; i < a.length + 1; ++i)
		for (int j = 1; j < b.length + 1; ++j) {
			const ulong substitutionCost = a[i - 1] == b[j - 1] ? 0 : 1;
			matrix[i][j] = min(matrix[i - 1][j - 1] + substitutionCost,
							   matrix[i][j - 1] + 1, 
							   matrix[i - 1][j] + 1
							);
		}

return matrix[a.length][b.length];
}

void main(string[] args) {
	import std.datetime.stopwatch: StopWatch, AutoStart;
	auto sw = StopWatch(AutoStart.no);
	sw.start();
	const auto result = levenshteinEditDistance(args[1], args[2]);
	sw.stop();

import std.stdio : writefln;

writefln("%s (%s microseconds).", result, sw.peek().total!"usecs");
}