Compiler Explorer

Source code

declare void @show1()
declare void @show2()
declare void @show3()
declare void @show4()

@c = external global i32, align 4

define void @check1(i32 %x, i32 %y) {
; CHECK-LABEL: @check1(
; CHECK: br i1 %cmp,
; CHECK-NOT: br i1 %cmp,
; CHECK-NOT: if.else:
; Check that control-dependent-dce is able to infer the value of %cmp
; used at the end of basic block if.then and thus that the IR after
; control-dependent-dce contains only one conditional branch based on
; %cmp in basic block entry.
entry:
  %cmp = icmp slt i32 %x, %y
  br i1 %cmp, label %if.then, label %if.end3

if.then:                                          ; preds = %entry
  call void () @show1()
  br i1 %cmp, label %if.then2, label %if.else

if.then2:                                         ; preds = %if.then
  call void () @show2()
  br label %if.end

if.else:                                          ; preds = %if.then
  call void () @show3()
  br label %if.end

if.end:                                           ; preds = %if.else, %if.then2
  br label %if.end3

if.end3:                                          ; preds = %if.end, %entry
  ret void
}

define void @check2(i32 %x, i32 %y) {
; CHECK-LABEL: @check2(
; CHECK: br i1 %cmp,
; CHECK-NOT: br i1 %cmp,
; CHECK-NOT: if.else:
; Check that control-dependent-dce is able to infer the value of %cmp
; used at the end of basic block do.body in a loop and thus that the
; IR after control-dependent-dce contains only one conditional branch
; based on %cmp in basic block entry.
entry:
  %cmp = icmp slt i32 %x, %y
  br i1 %cmp, label %if.then, label %if.end3

if.then:                                          ; preds = %entry
  call void () @show1()
  br label %do.body

do.body:                                          ; preds = %do.cond, %if.then
  call void () @show2()
  br i1 %cmp, label %if.then2, label %if.else

if.then2:                                         ; preds = %do.body
  call void () @show3()
  br label %if.end

if.else:                                          ; preds = %do.body
  call void () @show4()
  br label %if.end

if.end:                                           ; preds = %if.else, %if.then2
  %0 = load i32, i32* @c, align 4
  %dec = add nsw i32 %0, -1
  store i32 %dec, i32* @c, align 4
  br label %do.cond

do.cond:                                          ; preds = %if.end
  %1 = load i32, i32* @c, align 4
  %tobool = icmp ne i32 %1, 0
  br i1 %tobool, label %do.body, label %do.end

do.end:                                           ; preds = %do.cond
  br label %if.end3

if.end3:                                          ; preds = %do.end, %entry
  ret void
}