Compiler Explorer

Source code

const std = @import("std");
const builtin = @import("builtin");

comptime {
    _ = if (builtin.os.tag == .windows)
        struct {
            export const start_my_section: ?*i32 linksection("my_sec$a") = null;
            export const stop_my_section: ?*i32 linksection("my_sec$z") = null;
        }
    else if (builtin.os.tag.isDarwin())
        struct {
            export const dummy: ?*const i32 linksection("__DATA,my_section") = null;
            comptime {
                asm (
                    \\.global start_my_section
                    \\start_my_section = section$start$__DATA$my_section
                    \\
                    \\.global stop_my_section
                    \\stop_my_section = section$end$__DATA$my_section
                );
            }
        }
    else
        struct {
            export const dummy: ?*const i32 linksection("my_section") = null;
            comptime {
                asm (
                    \\.pushsection .init_array,"aw",%init_array
                    \\.reloc ., BFD_RELOC_NONE, my_section
                    \\.popsection
                    \\
                    \\.global start_my_section
                    \\start_my_section = __start_my_section
                    \\
                    \\.global stop_my_section
                    \\stop_my_section = __stop_my_section
                );
            }
        };
}

extern const start_my_section: ?*const i32;
extern const stop_my_section: ?*const i32;

pub inline fn registerResource(comptime x: i32) void {
    const section_name = if (builtin.os.tag == .windows)
        "my_sec$u"
    else if (builtin.os.tag.isDarwin())
        "__DATA,my_section"
    else
        "my_section";
    
    _ = struct {
        const val_ptr: *const i32 = &x;
        comptime {
            @export(&val_ptr, .{
                .name = "resource_" ++ @typeName(@This()),
                .section = section_name,
                .linkage = .strong,
                .visibility = if (builtin.os.tag == .windows) .default else .hidden,
            });
        }
    };
}

comptime {
    registerResource(5);
    registerResource(10);
    registerResource(15);
    registerResource(20);
    registerResource(25);
    registerResource(30);
    registerResource(35);
    registerResource(40);
    registerResource(45);
}

pub fn main() void {
    const start: [*]const ?*const i32 = @ptrCast(&start_my_section);
    const stop: [*]const ?*const i32 = @ptrCast(&stop_my_section);
    const num_resources = stop - start;
    for (start[0..num_resources]) |cursor| {
        if (cursor) |cur| std.debug.print("resource: {d}\n", .{cur.*});
    }
}