Compiler Explorer

Source code

module test_m
    use iso_fortran_env, only: dp => real64
    implicit none
contains

subroutine sumexp_1d( vec, val )
    real(dp), intent(in) , contiguous :: vec(:)
    real(dp), intent(out) :: val

val = sum( exp(vec) )
end

subroutine sumexp_2d( vecs, ans )
    real(dp), intent(in) , contiguous :: vecs(:,:)
    real(dp), intent(out) :: ans

ans = sum( exp( vecs ) )
end

subroutine sumexp_2d_n( n, vecs, ans )
    integer, intent(in) :: n
    real(dp), intent(in)  :: vecs(4,n)
    real(dp), intent(out) :: ans

ans = sum( exp( vecs ) )
end

subroutine sumexp_2d_loop( vecs, ans )
    real(dp), intent(in), contiguous :: vecs(:,:)
    real(dp), intent(out) :: ans
    integer :: i1, i2

ans = 0
    do i2 = 1, size( vecs, 2 )
    do i1 = 1, size( vecs, 1 )
        ans = ans + exp( vecs( i1, i2 ) )
    enddo
    enddo
end

end module

program main
    use test_m
    implicit none
    integer, parameter :: ndat = 10 ** 6
    real(dp), allocatable :: arr(:,:)
    real(dp) :: ans, val, c_start, c_end
    integer :: idat

allocate( arr( 4, ndat ) )
    call random_number( arr )

print *, "---- 1d ----"
    call cpu_time(c_start)
    ans = 0
    do idat = 1, ndat
        call sumexp_1d( arr( :, idat ), val )
        ans = ans + val
    enddo
    call cpu_time(c_end)

print *, "ans  = ", ans
    print *, "time = ", c_end - c_start

print *, "---- 2d ----"
    call cpu_time(c_start)
    call sumexp_2d( arr, ans )
    call cpu_time(c_end)

print *, "ans  = ", ans
    print *, "time = ", c_end - c_start

print *, "---- 2d - assumed size ----"
    call cpu_time(c_start)
    call sumexp_2d_n( ndat, arr, ans )
    call cpu_time(c_end)

print *, "ans  = ", ans
    print *, "time = ", c_end - c_start

print *, "--- 2d_loop ---"
    call cpu_time(c_start)
    call sumexp_2d_loop( arr, ans )
    call cpu_time(c_end)

print *, "ans  = ", ans
    print *, "time = ", c_end - c_start
end