Compiler Explorer

Source code

program app;

// В сигнатуре функции array of означает т. н. open array parameter — «любой массив с этим базовым типом»,
// в который можно передать статический array[3 .. 5] of integer, динамический array of integer, и даже слайс:
// printArr('Элементы a с #5 по #10: ', a[5 .. 10]).
// Индексы arg — всегда с 0 по High(arg).
// Физически arg передаётся как пара (указатель на первый элемент, количество элементов), то есть как ссылка на диапазон оригинального массива.
procedure printArr(const s: string; const arg: array of integer);
var i: integer;
begin
	write(s);
	for i := 0 to High(arg) do
		write(arg[i], ' ');
	writeln;
end;

procedure Bubblesort(var arg: array of integer);
var i, j: integer;
       t: integer;
begin
	for j := 1 to High(arg) do
		for i := 0 to High(arg) - j do
			if arg[i] > arg[i + 1] then
			begin
				t := arg[i];
				arg[i] := arg[i + 1];
				arg[i + 1] := t;
			end;
end;

var i: integer;
    Bars: array[0 .. 9] of integer; // Или (лучше) Bars: array of integer + SetLength(Bars, 10).

begin
	randomize;
	for i := 0 to High(Bars) do
		Bars[i] := random(10) + 1;
	printArr('Слитки: ', Bars);
	Bubblesort(Bars);
	printArr('Отсортированные слитки: ', Bars);
	writeln('Нечестное деление: ');
	for i := 0 to Length(Bars) div 2 - 1 do
		writeln(1 + i, ': ', Bars[High(Bars) - 2 * i], ' ', Bars[High(Bars) - 2 * i - 1]);
	writeln();
end.