Compiler Explorer

Source code

// fxc -T vs_5_0
// dxc -T vs_6_0

// Foo defines name of cbuffer for reflection purposes, but does not define a
// symbol available to reference in HLSL.
// Declarations inside a cbuffer block are global declarations and their scope
// is unaffected by the cbuffer declaration.
cbuffer Foo {
//   float f;                           // Offset:    0 Size:     4
    float f;
}

// 'k' is in $Globals, and $Globals is allocated first register(b0).
float k;

// One difference between FXC and DXC in nested case:
// FXC binds Bar before nested cbuffers, while DXC binds Bar after nested
// cbuffers.  FXC behavior seems better here.
cbuffer Bar {
//   float h;                           // Offset:    0 Size:     4
    float h;

// Nested cbuffer decl is legal, and doesn't impact the outer cbuffer
    // Second 'Foo' cbuffer is legal, as it does not define a symbol.
    // It shows up as another cbuffer named 'Foo' in reflection, rather than
    // adding to the previously declared 'Foo' cbuffer.
    cbuffer Foo {
//   float g;                           // Offset:    0 Size:     4
        float g;

// Nesting fine, even if the name matches the outer cbuffer.
        cbuffer Foo {
            float j;
        }
    }

// namespaces may be used inside or around cbuffer declarations
    namespace NS {
        // next declaration unaffected by nested cbuffer declaration
//   float NS::i;                       // Offset:    4 Size:     4
        float i;

// any other global declaration may exist inside a cbuffer block.
        float foo() {
            return f * i + g * h + j * k;
        }
    }

}

float main() : OUT {
    return NS::foo();
}