Compiler Explorer

Source code

declare void @llvm.memcpy.p0.p0.i64(ptr, ptr, i64, i1)

; Basic scenario: we *really* want SROA to remove the allocas

define i28 @test1(i28 %v) {
    %tmp = alloca i28
    %ret = alloca i28
    store i28 %v, ptr %tmp
    ; LLVM-18 no longer replaces this 4-byte memcpy by an i28 load/store pair, blocking SROA
    call void @llvm.memcpy.p0.p0.i64(ptr %ret, ptr %tmp, i64 4, i1 false)
    %r = load i28, ptr %ret
    ret i28 %r
}

define i28 @test2(i28 %v) {
    ; suggestion: SROA could promote the alloca access from i28 to i32
    %tmp = alloca i32
    %ret = alloca i32
    %v.prom = zext i28 %v to i32
    store i32 %v.prom, ptr %tmp
    ; always ok to replace this 4-byte memcpy by an i32 load/store pair
    call void @llvm.memcpy.p0.p0.i64(ptr %ret, ptr %tmp, i64 4, i1 false)
    %r.prom = load i32, ptr %ret
    %r = trunc i32 %r.prom to i28
    ; after SROA removes the allocas, the remaining zext/trunc cancel
    ret i28 %r
}

; Bug scenario with union access: SROA should not produce wrong code

define i32 @test3(i1 %c, ptr %p) {
    %tmp = alloca i28
    ; LLVM-17 miscompiles this by replacing the 4-byte memcpy by an i28 load/store pair 
    call void @llvm.memcpy.p0.p0.i64(ptr %tmp, ptr %p, i64 4, i1 false)
    %load1 = load i28, ptr %tmp
    %v1 = zext i28 %load1 to i32
    ; we access the 4th byte from the region, so this needs the complete 32 bits
    %p1 = getelementptr i8, ptr %tmp, i64 3
    %load2 = load i8, ptr %p1
    %v2 = zext i8 %load2 to i32
    %v3 = select i1 %c, i32 %v1, i32 %v2
    ret i32 %v3
}

define i32 @test4(i1 %c, ptr %p) {
    ; suggestion: again, SROA could promote the alloca access from i28 to i32
    ; the i8 access triggers SROA to replace the i32 access by an i24 complemented by the i8?
    ; in any case, it does not seem wrong
    %tmp = alloca i32
    call void @llvm.memcpy.p0.p0.i64(ptr %tmp, ptr %p, i64 4, i1 false)
    %load1.prom = load i32, ptr %tmp
    %load1 = trunc i32 %load1.prom to i28
    %v1 = zext i28 %load1 to i32
    %p1 = getelementptr i8, ptr %tmp, i64 3
    %load2 = load i8, ptr %p1
    %v2 = zext i8 %load2 to i32
    %v3 = select i1 %c, i32 %v1, i32 %v2
    ret i32 %v3
}