Compiler Explorer

Source code

#include <Arduino.h>

//analog value to gear lookup table
typedef struct { uint16_t adcVal;  uint8_t gearVal; } adcGear_t;
//table
const adcGear_t gearTable[] = {
    { 300, 0x00 }, //if <= adcVal, return gearVal
    { 420, 0x20 },
    { 540, 0x40 },
    { 665, 0x60 },
    { 800, 0x80 },
    { 905, 0xA0 },
    // >905 ? error value or ?
    { 0xffff, 0xA0 } //{ 0xffff, 0xff }
};
//read analog, convert to gear value from  lookup table
uint8_t readGear(){
    uint16_t v = analogRead (A0);
    const adcGear_t* gp = gearTable;
    for( ; v > gp->adcVal; gp++ ){}
    return gp->gearVal;
}

//blocking rx
uint8_t getRx(){
    int c;
    while( c = Serial.read(), c == -1 ){}
    return c;
}

//wait for rx, echo it, blocking
void echoRx(){ Serial.write( getRx() ); }

//wait for start of 8 byte packet, 30ms of silence should do
// [8x5ms=40ms...][60ms silence][8x5ms=40ms]...
void findRxSilence(){
    //wait for start of 8 byte packet, 30ms of silence should do
    // [8x5ms=40ms...][60ms silence][8x5ms=40ms]...
    //9600baud is ~1ms+ per byte, using delay(1) will be fine
    for( uint8_t i = 30; i; i--, delay(1) ){
        if( Serial.read() == -1 ) continue;
        i = 30; //start over if received something
    }
}

void setup(){
}

void loop(){

//wait for start of 8 byte packet.
    findRxSilence();
    //next 8 bytes should be a 'packet'

//first 5 just echo out
    for( uint8_t i = 0; i < 5; i++ ) echoRx();

//have plenty of time to get analog val here
    uint8_t gear = readGear();

//byte 6 replace with gear, calc checksum adjust
    uint8_t checksumAdjust= getRx() - gear;
    Serial.write( gear );

//byte 7 echo
    echoRx();

//byte 8 replace checksum
    Serial.write( getRx() + checksumAdjust );

//done, do again

}