Compiler Explorer

Source code

; test with
; sudo mount -t tmpfs -o size=1G,huge=always tmpfs /tmp/testd
; asm-link -nd yes.asm &&
; ./yes > testd/yesout && perf stat -d ./yes > testd/yesout       # warmup and run

global _start
_start:
;; All regs zeroed at the top of a static executable (except RSP)

SIZEPOW equ 16
;   mov  ecx, 8192
;   bts  ecx, 16      ; 1<<16 = 65536 x 4 bytes to fill.  4 bytes, any power of 2 vs. mov cx, imm16 limited to 65535
   bts  ecx, SIZEPOW
   mov  edx, ecx      ; size arg for sys_write in bytes; 1/4 of the actual buffer size

mov  eax, `y\ny\n`

;   sub  rsp, rdx
;   and  rsp, -65536   ; With: 631,4M cycles 357.6M insns.   Without:  651,3M cycles 359.4M instructions.  (times are somewhat noisy but there's a real difference)
                      ; static buffer is smaller code size, if we don't count the BSS as anything
                      ; and gives us cache-line / page alignment for kernel memcpy speed

;   mov  rdi, rsp
; push  rsp
; pop   rdi
   mov  edi, buf
   mov  esi, edi

rep  stosd        ; wmemset(rdi, eax, rcx)  4*rcx bytes
   
   lea   edi, [rcx + 1]
;   mov  edi, 1
.loop:
   mov  eax, edi     ; __NR_write = stdout fileno
   syscall
   test eax,eax      ;;;;;;;;;;; For benchmarking purposes only: abort on write fail
   jge  .loop
;   jmp  .loop

mov eax, 231
   xor edi, edi
   syscall

section .bss
 align 4096
 buf: resd 1<<SIZEPOW