Compiler Explorer

Source code

;  49 bytes, loops combined

MOV  SI, 82H+31		; end of command line input
	MOV  DI, OFFSET BUF+16 ; output string buffer
	MOV  AL, '$' 		; start with DOS string terminator
	STD 				; reverse direction of LODS/STOS
	STOSB 				; write '$' to output
	MOV  CL, 32	 		; loop 32 bits
BIT_LOOP:    
	LODSB 				; load next char into AL
	ROR  AX, 1 			; put LSB of bit char into next bit of byte value
	DEC  CX 			; decrement loop counter
	TEST CL, 00000111b 	; is new byte?
	JNZ  BIT_LOOP 		; keep looping
	MOV  AL, AH 		; put result into AL for display
DIGIT_LOOP:
	AAM 				; divide by 10, AL = remainder, AH = AL / 10
	OR   AL, '0' 		; ASCII convert
	STOSB 				; store char
	MOV  AL, AH			; put quotient back into AL	
	TEST AL, AL 		; quotient = 0?
	JNZ  DIGIT_LOOP		; if not, continue looping
	JCXZ DONE 			; finished last digit?
	MOV  AL, '.'		; if not, write a '.'
	STOSB
	JMP  BIT_LOOP 		; continue bit loop
DONE:
	MOV  DX, DI 		; beginning of string is output
	INC  DX 			; last STOSB, DI is off by one
	MOV  AH, 9 			; DOS API write string function
	INT  21H 			; write to console
	RET 				; return to DOS
BUF: